Das Open-Control-Projekt - Die Alternative zur C-Control-I


Das Forum zur C-Control-1
Welche C-Control-Varianten existieren?
Übersicht - Suchen - Neueste 50 Beiträge - Neuer Beitrag - Login - Registrieren
INFO - FAQ - CC2-Forum - CCPro-Forum 

 Demoprogramm: Schalthysterese verstehen und anwenden (mit Bild) Kategorie: Open-Micro/Open-Mini/Open-Midi/Open-Macro/Open-Maxi (von Dietmar, Homepage - 26.04.2022 21:07)
Dietmar nutzt:  Open-Micro, Open-Mini, Open-Midi, Open-Macro, Open-Maxi, Open-Mini Station


' ===========================================================================
' Demoprogramm: Schalthysterese verstehen und anwenden
' In OCBASIC 1.12a_e1 f├╝r Open-Maxi von Dietmar Harlos am 09. April 2022
' ===========================================================================

' Eine gute Erkl├Ąrung mit Bild gibt es auf folgender Internetseite:

' https://blog.wika.de/know-how/schaltfunktion-hysterese-bei-elektronischen-druckschaltern/

' Unter einer Hysterese versteht man im Allgemeinen die Differenz aus
' Schaltpunkt und R├╝ckschaltpunkt. Eine Hysterese ist grunds├Ątzlich
' unverzichtbar, denn falls Schalt- und R├╝ckschaltpunkt auf den identischen
' Wert festgelegt w├Ąren, so w├╝rde das zu steuernde System in Schwingung
' versetzt und somit instabil werden.

' In diesem Programm soll ein Digitalport gesetzt werden, wenn die Eingangs-
' spannung an einem Analog-Digital-Port 1,5 Volt ├╝berschreitet. W├╝rde man
' einschalten, wenn die Spannung gr├Â├čer 1,5 Volt ist und direkt unterhalb
' dieser Grenze ausschalten, w├╝rde st├Ąndig ein- und ausgeschaltet, wenn die
' Eingangsspannung nahe 1,5 Volt ist. Als L├Âsung wird hier bei gr├Â├čer/gleich
' 1,55 Volt ein- und bei kleiner/gleich 1,45 Volt ausgeschaltet. Die
' Hysterese hat also eine Gr├Â├če von 0,1 Volt.

' An dieser Stelle m├Âchte ich mich bei Dirk von "das |_ Team" und bei Norbert
' f├╝r ihre Unterst├╝tzung bedanken. In Memoriam Norbert Klein.

' --- Definitionen ----------------------------------------------------------

INCLUDE "omax.def"               'Definitionen f├╝r die Open-Maxi

DEFINE HYSTOBEN  317             '1024/5*1.55
DEFINE HYSTUNTEN 300             '1024/5*1.45

DEFINE adinput   AD[1]           'Eingang des Analog-Digital-Wandlers
DEFINE schalten  PORT[1]         'Einen Port ein- und ausschalten

DIM bitarray BYTE                'ein Bitarray
DIM debug    BIT[1] OF bitarray  'ist HIGH, wenn Debugging aktiv

DIM a,b,c BYTE                   'tempor├Ąre Variablen

' --- Hauptprogramm ---------------------------------------------------------

PrintSpc=ON    'Bei PRINT dezimale Zahlen mit f├╝hrendem Leerzeichen ausgeben
End2Host=ON    'Bei Programmende (siehe END) gleich in den Host-Modus wechseln

' Titel:

PRINT
PRINT "Schalthysterese"
PRINT "==============="

' Initialisierungen:

debug=ON 'OFF 'ON   'AD-Werte anzeigen

' Die AD-Ports liefern standardm├Ą├čig gerundete 8-Bit-Werte zwischen 0 und 255
' zur├╝ck, was den Spannungswerten 0 Volt bis 5 Volt entspricht. Mit folgendem
' Befehl wird auf gerundete 10 Bit umgeschaltet.

ADC1CFG=&b01001000  'AD-Wandler auf gerundete 10 Bit

schalten=OFF        'initialer Schaltzustand

' Hauptschleife des Programms:

WHILE TRUE

  IF debug THEN
    ?"adinput="adinput
  END IF

  IF adinput>=HYSTOBEN AND schalten=OFF THEN
    schalten=ON
    ?"Eingangsspannung hat oberen Hysteresepunkt erreicht oder ├╝berschritten."
  ELSE IF adinput<=HYSTUNTEN AND schalten=ON THEN
    schalten=OFF
    ?"Eingangsspannung hat unteren Hysteresepunkt erreicht oder unterschritten."
  END IF

  PAUSE 25

WEND

?:?"Programmende."
END            'Zur├╝ck in den Hostmodus. Neustart mit RETURN-Taste.

' --- Programmende ---------------------------------------------------------


Passender Link: Infosite zu den OM-Mikrocontrollern

Meine Homepage: http://ccintern.dharlos.de

 Antwort schreiben

Bisherige Antworten:

Re: Demoprogramm: Schalthysterese verstehen und anwenden (mit Bild) (von Christian - 27.04.2022 18:12)