Das Open-Control-Projekt - Die Alternative zur C-Control-I


Das Forum zur C-Control-1
Welche C-Control-Varianten existieren?
Übersicht - Suchen - Neueste 50 Beiträge - Neuer Beitrag - Login - Registrieren
INFO - FAQ - CC2-Forum - CCPro-Forum 

 Re: Zwei Ausgänge unabhängig mit einem Taster schalten? Kategorie: Open-Micro/Open-Mini/Open-Midi/Open-Macro/Open-Maxi (von Jens - 24.03.2013 19:44)
 Als Antwort auf Re: Zwei Ausgänge unabhängig mit einem Taster schalten? von Werner Schulze - 24.03.2013 15:33
Jens nutzt:  Open-Micro, Open-Mini, Open-Midi, Open-Macro, sonstige
Hallo Werner!

Hier mal mein Vorschlag:

' --- Betriebssystem konfigurieren ------------------------------------------
include "om.def"          ' Betriebssystem Daten der Open-Micro laden

' --- definition der Ports --------------------------------------------------
define Taster1    port[4] ' Taster Nr.1
define Relais1    port[5] ' Relais1
define Relais2    port[6] ' Relais2

' --- definition der Variablen ----------------------------------------------
define Ver1       byte    ' Verriegelung Taster Nr.1
define Flag       byte    ' Protokoll für Relais Zustände

' --- Voreinstellung und Initialisierung ------------------------------------
End2Host=ON               ' Bei Programmende in den HOST-Modus wechseln

' ---------------------------------------------------------------------------
' --- Hauptprogramm ---------------------------------------------------------
' ---------------------------------------------------------------------------
#Anfang

' Taster abfragen
IF Taster1 AND (Ver1 = 0) THEN  ' wenn Taster High, dann...
   Ver1 = 1               ' Verriegelung aktivieren
   Flag = Flag + 1        ' Protokoll hoch zählen
   IF Flag > 3 THEN Flag = 0  ' Reset, zurück zum Anfang
   Pause 2                ' 40ms Schalterentprellung
ENDIF
IF (NOT Taster1) AND (Ver1 = 1) THEN  ' wenn Taster Low, dann...
   Ver1 = 0               ' Verriegelung aufheben
   Pause 2                ' 40ms Schalterentprellung
ENDIF

' Relais einstellen
IF Flag = 0 THEN          ' wenn Protokoll 0, dann...
   Relais1 = OFF          ' Relais1 ausschalten
   Relais2 = OFF          ' Relais2 ausschalten
ENDIF
IF Flag = 1 THEN          ' wenn Protokoll 1, dann...
   Relais1 = ON           ' Relais1 einschalten
   Relais2 = OFF          ' Relais2 ausschalten
ENDIF
IF Flag = 2 THEN          ' wenn Protokoll 2, dann...
   Relais1 = ON           ' Relais1 einschalten
   Relais2 = ON           ' Relais2 einschalten
ENDIF
IF Flag = 3 THEN          ' wenn Protokoll 3, dann...
   Relais1 = OFF          ' Relais1 ausschalten
   Relais2 = ON           ' Relais2 einschalten
ENDIF

GOTO Anfang               ' Zurück
end                       ' Programmende

Getestet habe ich den Code nicht, sollte aber funktionieren...

LG Jens

 Antwort schreiben

Bisherige Antworten:

Re: Zwei Ausgänge unabhängig mit einem Taster schalten? (von Werner Schulze - 25.03.2013 20:57)
    Re: Zwei Ausgänge unabhängig mit einem Taster schalten? (von Jens - 26.03.2013 11:18)
        Re: Zwei Ausgänge unabhängig mit einem Taster schalten? (von Werner Schulze - 8.04.2013 22:44)
            Re: Zwei Ausgänge unabhängig mit einem Taster schalten? (von Jens - 9.04.2013 22:34)
                Re: Zwei Ausgänge unabhängig mit einem Taster schalten? (von Werner Schulze - 11.04.2013 23:57)